***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jul 12, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJS6461-AU   D   G   S
*****param & model definition***
.model  dmos  pmos(
+    l = 1e-6		  w = 1e-6		level = 3
+  vto = -2.		 kp =7.2)
.model  dds   d(
+   is = 4.891e-12	  n = 1.152		   rs = 8.149e-3
+  ikf = 2.677e-1
+   eg = 1.000	trs1 = 1.000e-3)
.model  dbody d(
+   is = 4.891e-12	  n = 1.082		   rs = 8.149e-3
+  cjo = 2.615e-10	  m = 3.822e-1		   vj = 6.211e-1
+   bv = 66 		ibv = 250e-6		 tbv1 = 5.115e-4		tt = 25n
+  ikf = 2.677e-1)
.model  inter  pmos(
+  vto = 0		 kp = 10		level = 1)
.model  dgd    d(
+  cjo = 5.070e-10	  m = 3.119e-1		   vj = 2.929e-1)
.param
+  cgs = 1.013e-9	cgd = 5.008e-10
+   rd = 2.459e-2	 ra = 2.000e-2		trd = 1.413e-2
*****function & circuit*****
rg	  G  1t   1
cgs	 1t   3   {cgs}
egv	  3  2t   table   {v(S, 1t)}
+((0   , 0   ),
+ (0.5 , 0   ),
+ (1   , 1   ),
+ (1.5 , 1.5 ),
+ (1.8 , 1.8 ),
+ (2   , 2   ),
+ (2.5 , 2.5 ),
+ (3   , 3   ),
+ (3.5 , 3.5 ),
+(4    , 3.94),
+ (4.5 , 4.18),
+ (5   , 4.33),
+ (6   , 4.6 ),
+ (8   , 5   ),
+ (10  , 5.5 ),
+ (20  , 11  ),
+ (22  , 22  ))
egt	  1  2t   value = {1.187e-3*limit(v(2t,3),-3,0)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd}
dds	  4   3   dds
dbody	  D   3   dbody
ra	  4   2   {ra}
rs	  3   5   1e-4
ls	  5   S   0.001n
m1       1t   8   6   6   inter
e1        8   6   4   1t  2
cgd	  7   4   {cgd}
rcgd      7   4   10meg
dgd       4   6   dgd
rdgd      4   6   10meg
m2        7   9  1t  1t   inter
e2        9  1t   4  1t   -2
.ends
*$
